Wolf Sheep Extended

No preview image

1 collaborator

Screen_shot_2021-10-29_at_8.40.47_am Corey Brady (Author)
Add Collaborator

Close

Tags

(This model has yet to be categorized with any tags)
Add New Tag

Close

Model group LS426_2013 | Visible to everyone | Changeable by everyone
Model was written in NetLogo 5.0.3 • Viewed 363 times • Downloaded 35 times • Run 0 times
Download the 'Wolf Sheep Extended' modelDownload this model • Embed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)

WHAT IS IT?

This model explores the stability of predator-prey ecosystems. Such a system is called unstable if it tends to result in extinction for one or more species involved. In contrast, a system is stable if it tends to maintain itself over time, despite fluctuations in population sizes.

HOW IT WORKS

There are two main variations to this model.

In the first variation, wolves and sheep wander randomly around the landscape, while the wolves look for sheep to prey on. Each step costs the wolves energy, and they must eat sheep in order to replenish their energy - when they run out of energy they die. To allow the population to continue, each wolf or sheep has a fixed probability of reproducing at each time step. This variation produces interesting population dynamics, but is ultimately unstable.

The second variation includes grass (green) in addition to wolves and sheep. The behavior of the wolves is identical to the first variation, however this time the sheep must eat grass in order to maintain their energy - when they run out of energy they die. Once grass is eaten it will only regrow after a fixed amount of time. This variation is more complex than the first, but it is generally stable.

The construction of this model is described in two papers by Wilensky & Reisman referenced below.

HOW TO USE IT

  1. Set the GRASS? switch to TRUE to include grass in the model, or to FALSE to only include wolves (red) and sheep (white).
  2. Adjust the slider parameters (see below), or use the default settings.
  3. Press the SETUP button.
  4. Press the GO button to begin the simulation.
  5. Look at the monitors to see the current population sizes
  6. Look at the POPULATIONS plot to watch the populations fluctuate over time

Parameters: INITIAL-NUMBER-SHEEP: The initial size of sheep population INITIAL-NUMBER-WOLVES: The initial size of wolf population SHEEP-GAIN-FROM-FOOD: The amount of energy sheep get for every grass patch eaten WOLF-GAIN-FROM-FOOD: The amount of energy wolves get for every sheep eaten SHEEP-REPRODUCE: The probability of a sheep reproducing at each time step WOLF-REPRODUCE: The probability of a wolf reproducing at each time step GRASS?: Whether or not to include grass in the model GRASS-REGROWTH-TIME: How long it takes for grass to regrow once it is eaten SHOW-ENERGY?: Whether or not to show the energy of each animal as a number

Notes:

  • one unit of energy is deducted for every step a wolf takes
  • when grass is included, one unit of energy is deducted for every step a sheep takes

THINGS TO NOTICE

When grass is not included, watch as the sheep and wolf populations fluctuate. Notice that increases and decreases in the sizes of each population are related. In what way are they related? What eventually happens?

Once grass is added, notice the green line added to the population plot representing fluctuations in the amount of grass. How do the sizes of the three populations appear to relate now? What is the explanation for this?

Why do you suppose that some variations of the model might be stable while others are not?

THINGS TO TRY

Try adjusting the parameters under various settings. How sensitive is the stability of the model to the particular parameters?

Can you find any parameters that generate a stable ecosystem that includes only wolves and sheep?

Try setting GRASS? to TRUE, but setting INITIAL-NUMBER-WOLVES to 0. This gives a stable ecosystem with only sheep and grass. Why might this be stable while the variation with only sheep and wolves is not?

Notice that under stable settings, the populations tend to fluctuate at a predictable pace. Can you find any parameters that will speed this up or slow it down?

Try changing the reproduction rules -- for example, what would happen if reproduction depended on energy rather than being determined by a fixed probability?

EXTENDING THE MODEL

There are a number ways to alter the model so that it will be stable with only wolves and sheep (no grass). Some will require new elements to be coded in or existing behaviors to be changed. Can you develop such a version?

NETLOGO FEATURES

Note the use of breeds to model two different kinds of "turtles": wolves and sheep. Note the use of patches to model grass.

Note use of the ONE-OF agentset reporter to select a random sheep to be eaten by a wolf.

RELATED MODELS

Look at Rabbits Grass Weeds for another model of interacting populations with different rules.

CREDITS AND REFERENCES

Wilensky, U. & Reisman, K. (1999). Connected Science: Learning Biology through Constructing and Testing Computational Theories -- an Embodied Modeling Approach. International Journal of Complex Systems, M. 234, pp. 1 - 12. (This model is a slightly extended version of the model described in the paper.)

Wilensky, U. & Reisman, K. (2006). Thinking like a Wolf, a Sheep or a Firefly: Learning Biology through Constructing and Testing Computational Theories -- an Embodied Modeling Approach. Cognition & Instruction, 24(2), pp. 171-209. http://ccl.northwestern.edu/papers/wolfsheep.pdf

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

COPYRIGHT AND LICENSE

Copyright 1997 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2000.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model 

;extensions [ nw ]


globals [grass]  ;; keep track of how much grass there is
;; Sheep and wolves are both breeds of turtle.
breed [sheep a-sheep]  ;; sheep is its own plural, so we use "a-sheep" as the singular.
breed [wolves wolf]


turtles-own [
  parents
  ancestors
  child-count   ;; how many children i have had
  last-reproduced  ;;age i last reproduced
  age           ;; added age variable.
  energy]       ;; both wolves and sheep have energy


patches-own [countdown]

to setup
  clear-all
  ask patches [ set pcolor green ]
  ;; check GRASS? switch.
  ;; if it is true, then grass grows and the sheep eat it
  ;; if it false, then the sheep don't need to eat
  if grass? [
    ask patches [
      set countdown random grass-regrowth-time ;; initialize grass grow clocks randomly
      set pcolor one-of [green brown]
    ]
  ]
  set-default-shape sheep "sheep"
  create-sheep initial-number-sheep  ;; create the sheep, then initialize their variables
  [
    set age 0
    set parents no-turtles 
    set ancestors no-turtles
    set color white
    set size 1.5  ;; easier to see
    set label-color blue - 2
    set energy random (2 * sheep-gain-from-food)
    setxy random-xcor random-ycor
  ]
  set-default-shape wolves "wolf"
  create-wolves initial-number-wolves  ;; create the wolves, then initialize their variables
  [
    set age 0
    set parents no-turtles
    set ancestors no-turtles
    set color black
    set size 2  ;; easier to see
    set energy random (2 * wolf-gain-from-food)
    setxy random-xcor random-ycor
  ]
  display-labels
  set grass count patches with [pcolor = green]
  reset-ticks
end 

to go
  if ( (not any? wolves) or (not any? sheep)  ) [ stop ]
  
  ask sheep [
    move
    if grass? [
      set energy energy - 1  ;; deduct energy for sheep only if grass? switch is on
      eat-grass
    ]
    set age age + 1
    death
    reproduce-sheep
  ]
  
  ask wolves [
    move
    set energy energy - 1  ;; wolves lose energy as they move
    catch-sheep
    set age age + 1
    death
    reproduce-wolves
  ]
  
  if grass? [ ask patches [ grow-grass ] ]
  
  set grass count patches with [pcolor = green]
  
  tick
  display-labels
end 

to move  ;; turtle procedure
  rt random 50
  lt random 50
  fd 1
end 

to eat-grass  ;; sheep procedure
  ;; sheep eat grass, turn the patch brown
  if pcolor = green [
    set pcolor brown
    set energy energy + sheep-gain-from-food  ;; sheep gain energy by eating
  ]
end 







;;
;;CHANGED PROCEDURE
;;

to reproduce-sheep  ;; sheep procedure
  if (age - last-reproduced > recovery-period )  ;if i can reproduce (take on mother role)
  [
    let my-parents parents
    let candidate-mates other sheep-here with [ (not member? myself parents) and (not member? self my-parents) ]
    
    if any? candidate-mates  ;only do this logic (reproduce) if there is a possible dad.
    [  
      let kids-ancestors ( turtle-set ancestors self )
      let kids-parents (turtle-set  self)
      ask one-of candidate-mates   ;dad adds genetic information & gets child credit.
      [ 
        set kids-ancestors (turtle-set kids-ancestors ancestors self ) 
        set kids-parents (turtle-set kids-parents self) 
        set child-count child-count + 1 
      ]
      
      set energy (energy / 2)   ; mom divides energy between herself and the offspring (no energy from dad)
      set last-reproduced age   ; start my timer for reproducing again.
      set child-count child-count + 1  
      hatch 1 [ 
        set ancestors kids-ancestors  ;know my ancestors
        set parents kids-parents      ;know my parents
        set age 0                     ;i'm newborn
        rt random-float 360 fd 1 ]   ;; hatch an offspring and move it forward 1 step
    ]
  ]
end 

;;OLD SHEEP REPRODUCTION
;to old-reproduce-sheep  ;; sheep procedure
;  if random-float 100 < sheep-reproduce [  ;; throw "dice" to see if you will reproduce
;    set energy (energy / 2)                ;; divide energy between parent and offspring
;    hatch 1 [ rt random-float 360 fd 1 ]   ;; hatch an offspring and move it forward 1 step
;  ]
;end

to reproduce-wolves  ;; wolf procedure
  if random-float 100 < wolf-reproduce [  ;; throw "dice" to see if you will reproduce
    set energy (energy / 2)               ;; divide energy between parent and offspring
    hatch 1 [ set age 0 rt random-float 360 fd 1 ]  ;; hatch an offspring and move it forward 1 step
  ]
end 

to catch-sheep  ;; wolf procedure
  let prey one-of sheep-here                    ;; grab a random sheep
  if prey != nobody                             ;; did we get one?  if so,
    [ ask prey [ die ]                          ;; kill it
      set energy energy + wolf-gain-from-food ] ;; get energy from eating
end 

to death  ;; turtle procedure
  ;; when energy dips below zero, die
  if energy < 0 [ die ]
end 

to grow-grass  ;; patch procedure
  ;; countdown on brown patches: if reach 0, grow some grass
  if pcolor = brown [
    ifelse countdown <= 0
      [ set pcolor green
        set countdown grass-regrowth-time ]
      [ set countdown countdown - 1 ]
  ]
end 

to display-labels
  ask turtles [ set label "" ]
  if show-energy? [
    ask wolves [ set label round energy ]
    if grass? [ ask sheep [ set label round energy ] ]
  ]
end 

to visualize-ancestry
  if ([pcolor] of one-of patches != black + 1 )
  [
    ask patches [ set pcolor black + 1 ]
    let denom max [ count sheep with [ member? myself parents ] ] of other sheep 
    show denom
    ask sheep [ 
      setxy 3 * xcor / 4 3 * ycor / 4 
      set shape "circle" 
      set size max (list .75 ( 4 * count sheep with [ member? myself parents ] / denom)  ) 
      set color 83 + 5 * age / (max [age] of sheep)]
  ]
  repeat 200 [
    layout-spring (sheep with [any? parents]) links 0.4 6 1
    display
  ]
  set-current-plot "offspring distribution"
  let toplot []
  ask sheep [ 
   set toplot lput (count sheep with [  member? myself parents ]) toplot
  ]
  histogram toplot
  
  set-current-plot "ancestry"
  let ancestryplot []
  ask sheep [ 
   set ancestryplot lput (count ancestors) ancestryplot
  ]
  histogram ancestryplot
end 

; Copyright 1997 Uri Wilensky.
; See Info tab for full copyright and license.

There are 3 versions of this model.

Uploaded by When Description Download
Corey Brady almost 12 years ago asdf Download this version
Corey Brady almost 12 years ago added button functionality Download this version
Corey Brady almost 12 years ago Initial upload Download this version

Attached files

No files

This model does not have any ancestors.

This model does not have any descendants.