SystemDynamics + ABM

;; LOGISTIC - Note that dt = 0.001 by default, but here it is initialized to 1 dt = 1 tick = 1 year.

;; system-dynamics-setup, system-dynamics-do-plot, and system-dynamics-go are automatically
;; generated by the System Dynamics Modeler.  The code can be viewed in the
;; Code Tab of the System Dynamics Modeler.

globals ;those not set in SD
[
   counter
   multiplier
   minmax
   pop-previous
   pop-change
   pop-plot
   old-pop
   upper-x
   upper-y
   predecessor
]

to setup
   ca
  
   system-dynamics-setup
   system-dynamics-do-plot
   set pop-change 0
   set pop-plot 0
   set old-pop init-pop
   set counter 0
   set multiplier 1
   set minmax 1.0E10  ;+/-9007199254740992 is range
   
   ;set graph display bounds assuming non-chaotic behavior   
   ifelse init-pop > carrying-capacity
   [ 
     set upper-y init-pop 
   ]
   [ 
     let uy list carrying-capacity (( birth-rate - death-rate ) * carrying-capacity )
     set upper-y max uy
   ]
   
   set upper-x Simlength
   
   set predecessor nobody
   
   print ( word "dt: " dt " Upper-x: " upper-x " Upper-y: " upper-y )
end 

to update-display1
  
  crt 1 [
    
    ;normalize to plot boundaries: min_range + (( current - min-data ) ( max-pxcor - min-pxcor)) / ( max-data - min-data)
    ;Max data range for x is length of simulation.  Max data range for y is carrying-capacity +- a buffer to show overshooet
    ;Max plot range for x is 1 less than max-pxcor to prevent last point from overshooting plot.  For y, 
   
    let x int ( ( ticks * ( max-pxcor - 1 ) ) / upper-x )
    let y int ( ( population * ( max-pycor - 1 ) ) / upper-y )

    set shape "circle"
    set size 1
    set color blue    
    set label ( precision pop-plot 0 ) 

    if pop-plot < 0 [ set color orange ]

    ;keep graphics on screen if chaotic behavior leads to wild fluctuations     
    if y < 0 [ set y 0 ] 
    if y > max-pycor - 1 [ set y max-pycor - 1 ]
    
    print ( word "         x: " x " y: " y " predecessor: " predecessor " at tick: " precision ticks 0 )
    setxy x y    
    if ticks >= 2.0 [ create-link-with predecessor ]
    set predecessor self

    
  ]
end 

to update-display2

  ;Depict individuals up to 100 tick units of time
    
  ifelse count turtles < 0 
  [ 
    crt 1 [
      let x ticks
      let y 2
      setxy x y
      set size 1
      set shape "circle"
      set color black
      ;set label count turtles
      print ( word "         population: " count turtles " births: " births " deaths: " deaths )
    ]
  ]
  [  
      ifelse births > 0
      [
        crt int births [
    
          let x random  ( max-pxcor - 1 )
          let y ( random  ( max-pycor - 11 ) ) + 10 
          setxy x y
    
          set size 1
          set shape "circle"
          print ( word "         turtle " who " born at x: " x " y: " y " at tick: " precision ticks 0 )
        ]
      ]
      [
        crt 1
        [
           let x ticks
           let y 4
           setxy x y
           set size 1
           set shape "circle"
           set color green
           ;set label precision births 1
        ]
      ]
    
      ifelse deaths > 0 
      [
        ask n-of int deaths turtles [
          print ( word "         turtle " who " died at at tick: " precision ticks 0 )
          die
        ]
      ]
      [
        crt 1
        [
          let x ticks
          let y 6
          set size 1
          set shape "circle"
          set color red
          ;set label precision deaths 1
        ]
      ]
  ]
end 

to update-plot
  
   set-current-plot "Population Size"
   system-dynamics-do-plot
   set-current-plot-pen "limit"
   plotxy ticks carrying-capacity
   
   set-current-plot "r"
   set-current-plot-pen "births"
   plotxy ticks births
   set-current-plot-pen "deaths"
   plotxy ticks deaths

   set-current-plot "dN"
   set-current-plot-pen "default"
   plotxy population pop-change
  
   set-current-plot "N2N1"
   set-current-plot-pen "default"
   plotxy pop-previous population 
end 

to go
  
  let mult multiplier / dt
  
  ;check status of simulation
  if ( ticks > SimLength ) [ stop ]
  if ( abs population >= minmax ) [ stop ]
 
  ;iterate 
  set counter counter + 1.0                ;number of iterations - i.e., "dt"
  set pop-previous population              ;record previous population in last dt
  system-dynamics-go                       ;one unit of dt
  set pop-change population - pop-previous ;change over 1 unit of dt
  
  if ( counter mod ( mult ) = 0 ) 
  [ 
    set multiplier multiplier + 1
    set pop-plot population - old-pop
    print ( word "Dt count: " counter " Tick count: " precision ticks 0 " Change per dt: " precision pop-change 3 " Change per tick: " precision pop-plot 3 " Population: " precision population 3 )
    
    ;combo box controls which way the main display is depicted - ON means population size over time with change as label.  OFF means individuals created and eliminated in a "network."
    if display-type = "display-population" [ update-display1 ]
    if display-type = "display-individuals" [ if ticks < max-pxcor - 1 [ update-display2 ]]
    
    set old-pop population

  ]
  
  update-plot
end