GenEvo 2 Genetic Drift

1 collaborator

WHAT IS IT?

This model is an example of genetic drift in a population of asexually reproducing bacteria E. coli. It starts with several types of E. coli, each with a different trait (which we represent with unique colors). The model shows that competing types of E. coli, each reproducing with equal likelihood on each turn, will ultimately converge on one type without any selection pressure forcing this convergence. The idea, explained in more detail in Dennett's Darwin's Dangerous Idea, is that trait drifts can occur without any particular purpose or 'selection pressure'.

HOW IT WORKS

The model starts with different colored E. coli cells, randomly distributed across the world. Each turn, each E. coli moves randomly around the world and has a chance (equal for all types of E. coli) of reproducing to form to two daughter cells of its type (of the same color).

If the total number of E. coli cells is greater than the carrying capacity, the maximum number of E. coli that is supported by the system, then E. coli cells are randomly killed until the number of E. coli is less than the carrying capacity.

By statistical advantage, a dominant color becomes more likely to 'win' and take over the population. However, because the process is random, there will usually be a series of dominant colors before one color finally wins.

Note that once a type of E. coli dies out, it can never come back.

HOW TO USE IT

The SETUP button initializes the model.

The GO button runs the model.

Use the CARRYING-CAPACITY slider to change the carrying capacity for the world.

Use the TRAITS slider to select the number of competing types of E. coli.

THINGS TO NOTICE

Notice that colors can achieve a high population count, but still fail to win the race.

Notice that in each simulation, the time required for a single type to become dominant varies. Check to see if an increase or decrease in the carrying capacity has any effect on how fast a color wins.

THINGS TO TRY

Try and modify the carrying capacity and number of traits to create a somewhat 'balanced' population (every trait has roughly the same population size). Is it even possible?

EXTENDING THE MODEL

Genetic drift is one mechanism of evolution. The other mechanism is natural selection. Can you incorporate natural selection and make a color of your choice win every time?

NETLOGO FEATURES

This model uses lots of different pens in the Plot editor (right-click on a plot and select 'Edit...') in order to have a multi-color plot.

RELATED MODELS

GenDrift Sample Models
GenEvo Curricular Models

HOW TO CITE

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

Dabholkar, S. and Wilensky, U. (2016). NetLogo GenEvo 2 Genetic Drift model. http://ccl.northwestern.edu/netlogo/models/GenEvo2GeneticDrift. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Please cite the NetLogo software as:

Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

To cite the GenEvo Systems Biology curriculum as a whole, please use:

Dabholkar, S. & Wilensky, U. (2016). GenEvo Systems Biology curriculum. http://ccl.northwestern.edu/curriculum/genevo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [ ecolis ecoli ]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;SETUP PROCEDURES ;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to setup     ; Sets up the population of bacteria (E. coli) randomly across the world.
  clear-all
  let color-list [ gray red brown yellow green cyan violet magenta ]

  create-ecolis number-of-traits [
    set shape "ecoli"
    setxy random-xcor random-ycor
    set color first color-list
    set color-list but-first color-list ; each type has a unique color so we remove this color form our list
  ]

  reset-ticks
end 

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;RUNTIME PROCEDURES ;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to go
  ask ecolis [
    move
    maybe-reproduce
    maybe-die
  ]
  tick
end 

to move   ; E. coli cells move randomly across the world.
  rt random-float 360
  fd 1
end 

to maybe-reproduce  ; E. coli cells reproduce based on random chance. This random chance of reproduction is same for all the cells.
  if random-float 100 > 99 [
    hatch 1 [
      rt random-float 360
      fd 1
    ]
  ]
end 

to maybe-die   ; random chance of death when the total population exceeds the carrying capacity
  if random (count ecolis) > carrying-capacity [
    die
  ]
end 


; Copyright 2016 Uri Wilensky.
; See Info tab for full copyright and license.

There is only one version of this model, created about 8 years ago by Sugat Dabholkar.

Attached files

File	Type	Description	Last updated
GenEvo 2 Genetic Drift .png	preview	Preview for 'GenEvo 2 Genetic Drift '	about 8 years ago, by Sugat Dabholkar	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo