breed [waters water]       ;; blue molecules
breed [anions anion]       ;; red molecules

globals [
  shrink      ;; how many steps right side has been shrunk
]

;; set up model with molecules randomly distributed across world
to setup [both-sides?]
  clear-all
  set-default-shape turtles "circle"
  set shrink 0
  draw-walls
  create-waters 100         ;; makes 100 blue water molecules
    [ set color blue
      randomize ]                 ;; and puts them on both sides
  create-anions 50         ;; makes 50 red anions
    [ set color red
      ifelse both-sides?          ;; and puts them on one or both sides depending
        [ randomize ]             ;; on which setup button was pressed
        [ randomize-right ] ]
  reset-ticks
end

;;turtle procedure that randomizes heading and position
to randomize
  setxy random-xcor random-ycor
  if any? patches in-radius 1 with [pcolor = green]
    [ randomize ] ;; keep trying until we don't land on or near green
end

;; turtle procedure that randomizes heading and position on the
;; right side of the membrane
to randomize-right
  setxy abs random-xcor
        random-ycor
  if any? patches in-radius 1 with [pcolor = green]
    [ randomize-right ] ;; try again until we don't land on or near green
end

;; observer procedure that makes the walls of the box
to draw-walls
  ;; don't let the window be bigger than the right chamber
  if (window-edge > (max-pycor - shrink))
    [ set window-edge (max-pycor - shrink) ]
  ask patches with [(pxcor = min-pxcor) or
                    ((pxcor < 0) and (abs pycor = max-pycor)) or
                    (pxcor >= max-pxcor - shrink) or
                    ((pxcor > 0) and (abs pycor >= max-pycor - shrink))]
    [ set pcolor green ]
  ask patches with [pxcor = 0]
    [ ifelse abs pycor < window-edge
        [ set pcolor black ]
        [ set pcolor green ] ]
  ;; make sure no turtles are embedded in the middle wall
  ;; if the window size changed
  ask turtles with [(pxcor = 0) and (pcolor = green)]
    [ randomize ]
end

to go
  ask turtles
    [ bounce
      fd 1 ]
  tick
end

;;observer procedure used to place 25 more red anions on the right
to add-anions-right
  create-anions 25
    [ set color red
      randomize-right ]
end

to bounce ;; turtle procedure
  ;; Note: The minimum on the window-edge slider is 2, not 0 or 1, because
  ;; this code does not correctly handle the case where window-edge is 1
  ;; (sometimes molecules get stuck in the window).
  ; if we're not about to land on green, we don't need to do any
  ; further checks
  if [pcolor] of patch-ahead 1 != green [ stop ]
  ; figure out where the walls are on this side of the box
  let box-edge-x max-pxcor
  let box-edge-y max-pycor
  if xcor >= 0
    [ set box-edge-x max-pxcor - shrink
      set box-edge-y max-pycor - shrink ]
  ; check: hitting left, right, or middle wall?
  if (abs [pxcor] of patch-ahead 1 = box-edge-x) or
     (([pxcor] of patch-ahead 1 = 0) and (pxcor != 0))
    ; if so, reflect heading around x axis
    [ set heading (- heading) ]
  ; check: hitting top or bottom wall, or edge of middle wall?
  if (abs [pycor] of patch-ahead 1 = box-edge-y) or
     (([pycor] of patch-ahead 1 = 0) and (pxcor = 0))
    ; if so, reflect heading around y axis
    [ set heading (180 - heading) ]
end

;; observer procedure that causes right side of divider to shrink (if amount is
;; positive) or expand (if amount is negative)
to shrink-or-expand [amount]
  set shrink (shrink + amount)
  ;; keep it within bounds
  if (shrink < 0)
    [ set shrink 0 ]
  if (shrink >= max-pxcor - 2)
    [ set shrink max-pxcor - 2 ]
  if (shrink >= max-pycor - 2)
    [ set shrink max-pycor - 2 ]
  clear-patches
  draw-walls
  ;; make sure no turtles are embedded in the walls
  ask turtles with [(xcor > 0) and (pcolor = green)]
    [ randomize-right ]
end


; Copyright 2001 Uri Wilensky.
; See Info tab for full copyright and license.
@#$#@#$#@
GRAPHICS-WINDOW
258
10
688
461
17
17
12.0
1
10
1
1
1
0
1
1
1
-17
17
-17
17
1
1
1
ticks
30.0

BUTTON
2
25
94
58
setup random
setup true\n;; true = reds on\n;; both sides
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
2
59
94
92
setup side
setup false\n;; false = reds all on\n;; one side
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
98
25
167
58
go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
168
25
252
58
add red
add-anions-right
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
30
116
126
149
shrink right
shrink-or-expand 1
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
127
116
230
149
expand right
shrink-or-expand -1
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
131
212
213
257
anions-right
count anions with\n[xcor >= 0]
3
1
11

MONITOR
45
212
123
257
anions-left
count anions with\n[xcor < 0]
3
1
11

BUTTON
144
154
250
187
change window
draw-walls
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
20
154
143
187
window-edge
window-edge
2
12
2
1
1
NIL
HORIZONTAL

PLOT
6
262
256
444
Equilibration Plot
Time
Number
0.0
50.0
-100.0
100.0
true
true
"" ""
PENS
"anions" 1.0 0 -2674135 true "" "let anions-left count anions with [xcor < 0]\nlet anions-right count anions with [xcor >= 0]\nplot (anions-right - anions-left)"
"water" 1.0 0 -13345367 true "" "let water-left count waters with [xcor < 0]\nlet water-right count waters with [xcor >= 0]\nplot (water-right - water-left)"
"midline" 1.0 0 -16777216 false ";; draw the x axis in black\nauto-plot-off\nset-current-plot-pen \"midline\"\nplot 0\nplotxy 10000 0\nauto-plot-on" ""

@#$#@#$#@
## WHAT IS IT?

This model follows on the Simple Kinetics 2 model.  In Simple Kinetics 2, we saw how changes to variables such as temperature, volume, and concentration affected the rate at which a chemical reaction reached an equilibrium state.  Here we model the same phenomenon based upon a physical separation.

This model investigates some laboratory methods that chemists use to purify chemicals.  Most of these methods are based upon physical properties of molecular separation. The same principles that affect chemical equilibrium affect physical equilibrium as well. By changing the variables of temperature, volume, and concentration, we can affect not only the speed at which a system reaches equilibrium, but also the nature of the distribution ratio. In this model, we watch how these factors affect the physical distribution of red molecules that are considered "dissolved" in a blue solvent.

## HOW TO USE IT

Setup the model by pressing either the SETUP-RANDOM or the SETUP-SIDE buttons at the top of the Interface tab.  SETUP-RANDOM distributes all the molecules randomly around the world. SETUP-SIDE distributes the blue molecules evenly, while placing the red molecules on the right side of the world.

Press GO to watch the molecules move about the world as they achieve equilibrium. The plot tracks the relative concentrations of each color molecule on each side of the central divider. If the red line dips below 0, there are more red molecules on the left side of the divider than on the right. If it rises above 0, there are more red molecules on the right side of the divider than on the left. The blue line plots the same relationship for blue molecules.

You can add more red molecules to the right side of the world by pressing ADD RED.

Similarly, you can shrink or expand the right side of the box with the buttons SHRINK RIGHT and EXPAND RIGHT, respectively.

Finally, to change the size of the connection window, move the WINDOW slider to your desired size and then press the CHANGE WINDOW button.

## THINGS TO NOTICE

Pay attention to the plot and compare it what you see in the world. Is there an equal number of blue and red molecules on each side of the divider according to the plot and according to what you see in the view?

## THINGS TO TRY

Run the model with several different states for each variable. Do you observe similar equilibrium effects to those seen in Simple Kinetics 2?  Are there significant differences?

Does the temperature affect the system in the same way it affected the chemical reaction in Simple Kinetics 2?  Why or why not?

How does changing the concentration affect the rate at which the molecules achieve equilibrium? Does this make sense?

## EXTENDING THE MODEL

The system we have established here always comes to an approximately identical equilibrium state, no matter how you change the variables. In the lab, this is not useful to chemists, who want to separate one type of molecule from another. Can you extend the model to separate all of the red molecules from the blue molecules?

Try adding another color of molecule to the system and randomly distributing all the molecules around the world. Can you devise a way to separate the new molecules from the red molecules?

Add a slider that allows you to alter the temperature of the system. Think about what effect cooling and heating the system would have on the molecules. Be sure to include a command in the procedures window that will execute your proposed effect.

## RELATED MODELS

Simple Kinetics 1, Simple Kinetics 2

## RELATED MODELS

Simple Kinetics 1
Simple Kinetics 2

## CREDITS AND REFERENCES

Thanks to Mike Stieff for his work on this model.


## HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

* Stieff, M. and Wilensky, U. (2001).  NetLogo Simple Kinetics 3 model.  http://ccl.northwestern.edu/netlogo/models/SimpleKinetics3.  Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
* Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

## COPYRIGHT AND LICENSE

Copyright 2001 Uri Wilensky.

![CC BY-NC-SA 3.0](http://i.creativecommons.org/l/by-nc-sa/3.0/88x31.png)

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License.  To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227.

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.4
@#$#@#$#@
setup false
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@
